[FEA] Add option to build faiss shared libs

build.sh

@@ -42,6 +42,7 @@ PYTHON_DEPS_CLONE=${REPODIR}/python/external_repositories
 BUILD_DIRS="${CPP_RAFT_BUILD_DIR} ${PY_RAFT_BUILD_DIR} ${PYTHON_DEPS_CLONE}"
 
 # Set defaults for vars modified by flags to this script
+CMAKE_LOG_LEVEL=""
 VERBOSE_FLAG=""
 BUILD_ALL_GPU_ARCH=0
 BUILD_GTEST=OFF
@@ -83,6 +84,7 @@ fi
 # Process flags
 if hasArg -v; then
     VERBOSE_FLAG=-v
+    CMAKE_LOG_LEVEL="--log-level=VERBOSE"
     set -x
 fi
 if hasArg -g; then
@@ -141,13 +143,13 @@ if (( ${NUMARGS} == 0 )) || hasArg cppraft; then
         echo "Building for *ALL* supported GPU architectures..."
     fi
 
-    cmake -S ${REPODIR}/cpp -B ${CPP_RAFT_BUILD_DIR} \
+    cmake -S ${REPODIR}/cpp -B ${CPP_RAFT_BUILD_DIR} ${CMAKE_LOG_LEVEL} \
           -DCMAKE_INSTALL_PREFIX=${INSTALL_PREFIX} \
           -DCMAKE_CUDA_ARCHITECTURES=${RAFT_CMAKE_CUDA_ARCHITECTURES} \
           -DNVTX=${NVTX} \
           -DDISABLE_DEPRECATION_WARNING=${BUILD_DISABLE_DEPRECATION_WARNING} \
           -DBUILD_GTEST=${BUILD_GTEST} \
-          -DBUILD_STATIC_FAISS=${BUILD_STATIC_FAISS}
+          -DRAFT_USE_FAISS_STATIC=${BUILD_STATIC_FAISS}
 
 
     # Run all c++ targets at once

cpp/CMakeLists.txt

@@ -15,7 +15,7 @@
 #=============================================================================
 
 cmake_minimum_required(VERSION 3.20.1 FATAL_ERROR)
-file(DOWNLOAD https://raw.githubusercontent.com/rapidsai/rapids-cmake/branch-21.10/RAPIDS.cmake
+file(DOWNLOAD https://raw.githubusercontent.com/rapidsai/rapids-cmake/branch-21.12/RAPIDS.cmake
     ${CMAKE_BINARY_DIR}/RAPIDS.cmake)
 include(${CMAKE_BINARY_DIR}/RAPIDS.cmake)
 include(rapids-cmake)
@@ -49,6 +49,8 @@ option(DISABLE_DEPRECATION_WARNINGS "Disable depreaction warnings " ON)
 option(DISABLE_OPENMP "Disable OpenMP" OFF)
 option(NVTX "Enable nvtx markers" OFF)
 
+option(RAFT_USE_FAISS_STATIC "Build and statically link the FAISS library for nearest neighbors search on GPU" ON)
+
 message(VERBOSE "RAFT: Build RAFT unit-tests: ${BUILD_TESTS}")
 message(VERBOSE "RAFT: Enable detection of conda environment for dependencies: ${DETECT_CONDA_ENV}")
 message(VERBOSE "RAFT: Disable depreaction warnings " ${DISABLE_DEPRECATION_WARNINGS})
@@ -100,13 +102,14 @@ endif()
 # add third party dependencies using CPM
 rapids_cpm_init()
 
-include(cmake/thirdparty/get_thrust.cmake)
 include(cmake/thirdparty/get_rmm.cmake)
 include(cmake/thirdparty/get_cuco.cmake)
+# CPMFindPackage(faiss) so it's available for raft consumers to use
+include(cmake/thirdparty/get_faiss.cmake)
+# CPMFindPackage(GTest) so it's available for raft consumers to use
+include(cmake/thirdparty/get_gtest.cmake)
 
 if(BUILD_TESTS)
-  include(cmake/thirdparty/get_faiss.cmake)
-  include(cmake/thirdparty/get_gtest.cmake)
   include(cmake/thirdparty/get_nccl.cmake)
   include(cmake/thirdparty/get_ucx.cmake)
 endif()
@@ -161,11 +164,22 @@ and common functions for the analytics components of RAPIDS.
 
 ]=])
 
+set(raft_code_string
+[=[
+if(TARGET faiss AND (NOT TARGET faiss::faiss))
+    add_library(faiss::faiss ALIAS faiss)
+elseif(TARGET faiss::faiss AND (NOT TARGET faiss))
+    add_library(faiss ALIAS faiss::faiss)
+endif()
+]=]
+)
+
  rapids_export(INSTALL raft
     EXPORT_SET raft-exports
     GLOBAL_TARGETS raft # since we can't hook into EXPORT SETS
     NAMESPACE raft::
     DOCUMENTATION doc_string
+    FINAL_CODE_BLOCK raft_code_string
     )
 
 ##############################################################################
@@ -177,6 +191,7 @@ rapids_export(BUILD raft
     LANGUAGES CUDA
     DOCUMENTATION doc_string
     NAMESPACE raft::
+    FINAL_CODE_BLOCK raft_code_string
     )
 
 ##############################################################################

cpp/cmake/thirdparty/get_cuco.cmake

@@ -22,7 +22,7 @@ function(find_and_configure_cuco VERSION)
       INSTALL_EXPORT_SET  raft-exports
       CPM_ARGS
         GIT_REPOSITORY https://github.com/NVIDIA/cuCollections.git
-        GIT_TAG        729857a5698a0e8d8f812e0464f65f37854ae17b
+        GIT_TAG        23c9a1fdbc06c29687c54016f6bb0b503535032c
         OPTIONS        "BUILD_TESTS OFF"
                        "BUILD_BENCHMARKS OFF"
                        "BUILD_EXAMPLES OFF"

cpp/cmake/thirdparty/get_faiss.cmake

@@ -15,39 +15,54 @@
 #=============================================================================
 
 function(find_and_configure_faiss)
-    set(oneValueArgs VERSION PINNED_TAG)
+    set(oneValueArgs VERSION PINNED_TAG BUILD_STATIC_LIBS)
     cmake_parse_arguments(PKG "${options}" "${oneValueArgs}"
                           "${multiValueArgs}" ${ARGN} )
 
-    rapids_find_generate_module(FAISS
+    rapids_find_generate_module(faiss
         HEADER_NAMES  faiss/IndexFlat.h
         LIBRARY_NAMES faiss
     )
 
-    rapids_cpm_find(FAISS ${PKG_VERSION}
-        GLOBAL_TARGETS  faiss
+    set(BUILD_SHARED_LIBS OFF)
+    if (NOT BUILD_STATIC_LIBS)
+        set(BUILD_SHARED_LIBS ON)
+    endif()
+
+    rapids_cpm_find(faiss ${PKG_VERSION}
+        GLOBAL_TARGETS     faiss::faiss
+        INSTALL_EXPORT_SET raft-exports
         CPM_ARGS
           GIT_REPOSITORY  https://github.com/facebookresearch/faiss.git
           GIT_TAG         ${PKG_PINNED_TAG}
           OPTIONS
             "FAISS_ENABLE_PYTHON OFF"
-            "BUILD_SHARED_LIBS OFF"
             "CUDAToolkit_ROOT ${CUDAToolkit_LIBRARY_DIR}"
             "FAISS_ENABLE_GPU ON"
             "BUILD_TESTING OFF"
             "CMAKE_MESSAGE_LOG_LEVEL VERBOSE"
     )
 
-    if(FAISS_ADDED)
-      set(FAISS_GPU_HEADERS ${FAISS_SOURCE_DIR} PARENT_SCOPE)
+    if(TARGET faiss AND NOT TARGET faiss::faiss)
+        add_library(faiss::faiss ALIAS faiss)
     endif()
 
-    if(TARGET faiss AND NOT TARGET FAISS::FAISS)
-        add_library(FAISS::FAISS ALIAS faiss)
+    if(faiss_ADDED)
+        rapids_export(BUILD faiss
+            EXPORT_SET faiss-targets
+            GLOBAL_TARGETS faiss
+            NAMESPACE faiss::)
     endif()
 
+    # We generate the faiss-config files when we built faiss locally, so always do `find_dependency`
+    rapids_export_package(BUILD faiss raft-exports)
+
+    # Tell cmake where it can find the generated faiss-config.cmake we wrote.
+    include("${rapids-cmake-dir}/export/find_package_root.cmake")
+    rapids_export_find_package_root(BUILD faiss [=[${CMAKE_CURRENT_LIST_DIR}]=] raft-exports)
 endfunction()
 
 find_and_configure_faiss(VERSION    1.7.0
                          PINNED_TAG  bde7c0027191f29c9dadafe4f6e68ca0ee31fb30
+                         BUILD_STATIC_LIBS ${RAFT_USE_FAISS_STATIC}
                         )

cpp/cmake/thirdparty/get_gtest.cmake

@@ -17,7 +17,19 @@
 function(find_and_configure_gtest )
 
     include(${rapids-cmake-dir}/cpm/gtest.cmake)
-    rapids_cpm_gtest()
+    rapids_cpm_gtest(BUILD_EXPORT_SET raft-exports
+                     INSTALL_EXPORT_SET raft-exports)
+
+    if(GTest_ADDED)
+        rapids_export(BUILD GTest
+          VERSION ${GTest_VERSION}
+          EXPORT_SET GTestTargets
+          GLOBAL_TARGETS gtest gmock gtest_main gmock_main
+          NAMESPACE GTest::)
+
+        include("${rapids-cmake-dir}/export/find_package_root.cmake")
+        rapids_export_find_package_root(BUILD GTest [=[${CMAKE_CURRENT_LIST_DIR}]=] raft-exports)
+    endif()
 
 endfunction()
 

cpp/test/CMakeLists.txt

@@ -117,20 +117,14 @@ target_compile_options(test_raft
 target_include_directories(test_raft
     PUBLIC  "$<BUILD_INTERFACE:${RAFT_SOURCE_DIR}/include>"
             "$<BUILD_INTERFACE:${RAFT_SOURCE_DIR}/test>"
-            "${FAISS_GPU_HEADERS}"
 )
 
 
 target_link_libraries(test_raft
 PRIVATE
-  CUDA::cublas
-  CUDA::curand
-  CUDA::cusolver
-  CUDA::cudart
-  CUDA::cusparse
-  rmm::rmm
-  cuco::cuco
-  FAISS::FAISS
+  raft::raft
+  NCCL::NCCL
+  faiss::faiss
   GTest::gtest
   GTest::gtest_main
   Threads::Threads