Add Avenger Backlog Notifications

config/config.exs

@@ -72,10 +72,6 @@ config :sentry,
   root_source_code_path: File.cwd!(),
   context_lines: 5
 
-# Import environment specific config. This must remain at the bottom
-# of this file so it overrides the configuration defined above.
-import_config "#{Mix.env()}.exs"
-
 # Configure Phoenix Swagger
 config :cadet, :phoenix_swagger,
   swagger_files: %{
@@ -93,3 +89,22 @@ config :guardian, Guardian.DB,
   token_types: ["refresh"],
   # default: 60 minute
   sweep_interval: 180
+
+config :cadet, Oban,
+  repo: Cadet.Repo,
+  plugins: [
+    # keep
+    {Oban.Plugins.Pruner, max_age: 60},
+    {Oban.Plugins.Cron,
+     crontab: [
+       {"@daily", Cadet.Workers.NotificationWorker,
+        args: %{"notification_type" => "avenger_backlog"}}
+     ]}
+  ],
+  queues: [default: 10, notifications: 1]
+
+config :cadet, Cadet.Mailer, adapter: Bamboo.LocalAdapter
+
+# Import environment specific config. This must remain at the bottom
+# of this file so it overrides the configuration defined above.
+import_config "#{Mix.env()}.exs"

config/prod.exs

@@ -44,3 +44,5 @@ config :logger, level: :info
 config :ex_aws,
   access_key_id: [:instance_role],
   secret_access_key: [:instance_role]
+
+config :cadet, Cadet.Mailer, adapter: Bamboo.SesAdapter

config/test.exs

@@ -88,3 +88,9 @@ config :arc, storage: Arc.Storage.Local
 
 if "test.secrets.exs" |> Path.expand(__DIR__) |> File.exists?(),
   do: import_config("test.secrets.exs")
+
+config :cadet, Oban,
+  repo: Cadet.Repo,
+  testing: :manual
+
+config :cadet, Cadet.Mailer, adapter: Bamboo.TestAdapter

lib/cadet/accounts/course_registrations.ex

@@ -63,6 +63,13 @@ defmodule Cadet.Accounts.CourseRegistrations do
     |> Repo.all()
   end
 
+  def get_staffs(course_id) do
+    CourseRegistration
+    |> where(course_id: ^course_id)
+    |> where(role: :staff)
+    |> Repo.all()
+  end
+
   def get_users(course_id, group_id) when is_ecto_id(group_id) and is_ecto_id(course_id) do
     CourseRegistration
     |> where([cr], cr.course_id == ^course_id)
@@ -200,4 +207,23 @@ defmodule Cadet.Accounts.CourseRegistrations do
       {:error, changeset} -> {:error, {:bad_request, full_error_messages(changeset)}}
     end
   end
+
+  def get_avenger_of(student_id) when is_ecto_id(student_id) do
+    CourseRegistration
+    |> Repo.get_by(id: student_id)
+    |> Repo.preload(:group)
+    |> Map.get(:group)
+    |> case do
+      nil ->
+        nil
+
+      group ->
+        avenger_id = Map.get(group, :leader_id)
+
+        CourseRegistration
+        |> where([cr], cr.id == ^avenger_id)
+        |> preload(:user)
+        |> Repo.one()
+    end
+  end
 end

lib/cadet/accounts/user.ex

@@ -20,6 +20,7 @@ defmodule Cadet.Accounts.User do
     field(:username, :string)
     field(:provider, :string)
     field(:super_admin, :boolean)
+    field(:email, :string)
 
     belongs_to(:latest_viewed_course, Course)
     has_many(:courses, CourseRegistration)

lib/cadet/application.ex

@@ -20,7 +20,9 @@ defmodule Cadet.Application do
       # Start the GuardianDB sweeper
       worker(Guardian.DB.Token.SweeperServer, []),
       # Start the Quantum scheduler
-      worker(Cadet.Jobs.Scheduler, [])
+      worker(Cadet.Jobs.Scheduler, []),
+      # Start the Oban instance
+      {Oban, Application.fetch_env!(:cadet, Oban)}
     ]
 
     children =

lib/cadet/assessments/assessments.ex

@@ -721,11 +721,24 @@ defmodule Cadet.Assessments do
     |> Repo.one()
   end
 
+  def get_submission_by_id(submission_id) when is_ecto_id(submission_id) do
+    Submission
+    |> where(id: ^submission_id)
+    |> join(:inner, [s], a in assoc(s, :assessment))
+    |> preload([_, a], assessment: a)
+    |> Repo.one()
+  end
+
   def finalise_submission(submission = %Submission{}) do
     with {:status, :attempted} <- {:status, submission.status},
          {:ok, updated_submission} <- update_submission_status_and_xp_bonus(submission) do
       # Couple with update_submission_status_and_xp_bonus to ensure notification is sent
       Notifications.write_notification_when_student_submits(submission)
+      # Send email notification to avenger
+      %{notification_type: "assessment_submission", submission_id: updated_submission.id}
+      |> Cadet.Workers.NotificationWorker.new()
+      |> Oban.insert()
+
       # Begin autograding job
       GradingJob.force_grade_individual_submission(updated_submission)
 
@@ -1151,7 +1164,8 @@ defmodule Cadet.Assessments do
           {:ok, String.t()}
   def all_submissions_by_grader_for_index(
         grader = %CourseRegistration{course_id: course_id},
-        group_only \\ false
+        group_only \\ false,
+        ungraded_only \\ false
       ) do
     show_all = not group_only
 
@@ -1161,6 +1175,11 @@ defmodule Cadet.Assessments do
         else:
           "where s.student_id in (select cr.id from course_registrations cr inner join groups g on cr.group_id = g.id where g.leader_id = $2) or s.student_id = $2"
 
+    ungraded_where =
+      if ungraded_only,
+        do: "where s.\"gradedCount\" < assts.\"questionCount\"",
+        else: ""
+
     params = if show_all, do: [course_id], else: [course_id, grader.id]
 
     # We bypass Ecto here and use a raw query to generate JSON directly from
@@ -1200,7 +1219,7 @@ defmodule Cadet.Assessments do
                group by s.id) s
              inner join
                (select
-                 a.id, to_json(a) as jsn
+                 a.id, a."questionCount", to_json(a) as jsn
                from
                  (select
                    a.id,
@@ -1240,6 +1259,7 @@ defmodule Cadet.Assessments do
                  from course_registrations cr
                    inner join
                    users u on u.id = cr.user_id) cr) unsubmitters on s.unsubmitted_by_id = unsubmitters.id
+             #{ungraded_where}
            ) q
            """,
            params

lib/cadet/courses/courses.ex

@@ -82,6 +82,12 @@ defmodule Cadet.Courses do
     end
   end
 
+  def get_all_course_ids do
+    Course
+    |> select([c], c.id)
+    |> Repo.all()
+  end
+
   defp retrieve_course(course_id) when is_ecto_id(course_id) do
     Course
     |> where(id: ^course_id)
@@ -233,8 +239,8 @@ defmodule Cadet.Courses do
             )
             |> where(course_id: ^course_id)
             |> Repo.one()} do
-      # It is ok to assume that user course registions already exist, as they would have been created
-      # in the admin_user_controller before calling this function
+      # It is ok to assume that user course registions already exist, as they would
+      # have been created in the admin_user_controller before calling this function
       case role do
         # If student, update his course registration
         :student ->

lib/cadet/email.ex

@@ -0,0 +1,40 @@
+defmodule Cadet.Email do
+  @moduledoc """
+  Contains methods for sending email notifications.
+  """
+  use Bamboo.Phoenix, view: CadetWeb.EmailView
+  import Bamboo.Email
+
+  def avenger_backlog_email(template_file_name, avenger, ungraded_submissions) do
+    if is_nil(avenger.email) do
+      nil
+    else
+      base_email()
+      |> to(avenger.email)
+      |> assign(:avenger_name, avenger.name)
+      |> assign(:submissions, ungraded_submissions)
+      |> subject("Backlog for #{avenger.name}")
+      |> render("#{template_file_name}.html")
+    end
+  end
+
+  def assessment_submission_email(template_file_name, avenger, student, submission) do
+    if is_nil(avenger.email) do
+      nil
+    else
+      base_email()
+      |> to(avenger.email)
+      |> assign(:avenger_name, avenger.name)
+      |> assign(:student_name, student.name)
+      |> assign(:assessment_title, submission.assessment.title)
+      |> subject("New submission for #{submission.assessment.title}")
+      |> render("#{template_file_name}.html")
+    end
+  end
+
+  defp base_email do
+    new_email()
+    |> from("noreply@sourceacademy.org")
+    |> put_html_layout({CadetWeb.LayoutView, "email.html"})
+  end
+end

lib/cadet/jobs/scheduler.ex

@@ -1,5 +1,8 @@
 # credo:disable-for-this-file Credo.Check.Readability.ModuleDoc
 # @moduledoc is actually generated by a macro inside Quantum
 defmodule Cadet.Jobs.Scheduler do
+  @moduledoc """
+  Quantum is used for scheduling jobs with cron jobs.
+  """
   use Quantum, otp_app: :cadet
 end

lib/cadet/mailer.ex

@@ -0,0 +1,6 @@
+defmodule Cadet.Mailer do
+  @moduledoc """
+  Mailer used to sent notification emails.
+  """
+  use Bamboo.Mailer, otp_app: :cadet
+end