Add frontend module

iac/certificate.tf

@@ -1,4 +1,17 @@
 data "aws_acm_certificate" "certificate" {
-  domain   = "*.worldcubeassociation.org"
+  domain   = "*.${var.domain_name}"
   statuses = ["ISSUED"]
 }
+
+provider "aws" {
+  region = "us-east-1"
+  alias  = "us_east_1"
+}
+
+data "aws_acm_certificate" "certificate_us_east_1" {
+  domain   = "*.${var.domain_name}"
+  statuses = ["ISSUED"]
+
+  provider = aws.us_east_1
+}
+

iac/frontend.tf

@@ -0,0 +1,10 @@
+module "tnoodle_frontend" {
+  source = "./modules/frontend"
+
+  aws_region      = var.aws_region
+  project_name    = var.tnoodle_name
+  zone_id         = data.aws_ssm_parameter.wca_zone_id.value
+  domain_name     = var.domain_name
+  org_name        = var.org_name
+  certificate_arn = data.aws_acm_certificate.certificate_us_east_1.arn
+}

iac/modules/frontend/README.md

@@ -0,0 +1,3 @@
+# Frontend Module
+
+This holds the infra to deploy TNoodle's frontend.

iac/modules/frontend/cloudfront.tf

@@ -0,0 +1,37 @@
+module "cdn" {
+  source = "cloudposse/cloudfront-s3-cdn/aws"
+
+  # Cloud Posse recommends pinning every module to a specific version
+  version = "0.92.0"
+
+  origin_bucket             = aws_s3_bucket.fontend_bucket.id
+  s3_access_logging_enabled = false
+  logging_enabled           = false
+  cached_methods            = ["HEAD", "GET", "OPTIONS"]
+  default_ttl               = "86400"
+  name                      = "cdn"
+  stage                     = terraform.workspace
+  namespace                 = var.domain_name
+  error_document            = "index.html"
+  aliases                   = ["${var.project_name}.${var.domain_name}"]
+  dns_alias_enabled         = false
+  acm_certificate_arn       = var.certificate_arn
+  minimum_protocol_version  = "TLSv1.2_2021"
+
+  custom_error_response = [
+    {
+      error_caching_min_ttl = 10,
+      error_code            = 403
+      response_code         = 403
+      response_page_path    = "/index.html"
+    },
+    {
+      error_caching_min_ttl = 10,
+      error_code            = 404
+      response_code         = 404
+      response_page_path    = "/index.html"
+    }
+  ]
+
+  depends_on = [aws_s3_bucket.fontend_bucket]
+}

iac/modules/frontend/outputs.tf

@@ -0,0 +1,12 @@
+output "deployment_bucket" {
+  value = aws_s3_bucket.fontend_bucket.bucket
+}
+
+output "cf_distribution_id" {
+  value = module.cdn.cf_id
+}
+
+output "cf_domain_name" {
+  value = module.cdn.cf_domain_name
+}
+

iac/modules/frontend/route53.tf

@@ -0,0 +1,11 @@
+resource "aws_route53_record" "project_record" {
+  zone_id = var.zone_id
+  name    = var.project_name
+  type    = "A"
+
+  alias {
+    name                   = module.cdn.cf_domain_name
+    evaluate_target_health = true
+    zone_id                = module.cdn.cf_hosted_zone_id
+  }
+}

iac/modules/frontend/s3.tf

@@ -0,0 +1,3 @@
+resource "aws_s3_bucket" "fontend_bucket" {
+  bucket = "${var.org_name}-${var.project_name}-frontend"
+}

iac/modules/frontend/variables.tf

@@ -0,0 +1,23 @@
+variable "aws_region" {
+  description = "AWS Region"
+}
+
+variable "project_name" {
+  description = "The name of this project"
+}
+
+variable "zone_id" {
+  description = "The Route53 zone ID"
+}
+
+variable "domain_name" {
+  description = "The domain name, web URL"
+}
+
+variable "org_name" {
+  description = "The name of the organization"
+}
+
+variable "certificate_arn" {
+  description = "The ARN of the ACM certificate"
+}

iac/outputs.tf

@@ -0,0 +1,3 @@
+output "tnoodle_distribution_id" {
+  value = module.tnoodle_frontend.cf_distribution_id
+}

iac/route53.tf

@@ -1,7 +1,7 @@
-# tnoodle.worldcubeassociation.org
+# tnoodle-api.worldcubeassociation.org
 resource "aws_route53_record" "project_record" {
   zone_id = data.aws_ssm_parameter.wca_zone_id.value
-  name    = var.tnoodle_name
+  name    = "${var.tnoodle_name}-api"
   type    = "A"
 
   alias {
@@ -11,10 +11,10 @@ resource "aws_route53_record" "project_record" {
   }
 }
 
-# scramble.worldcubeassociation.org
-resource "aws_route53_record" "project_record" {
+# scramble-api.worldcubeassociation.org
+resource "aws_route53_record" "alternative_record" {
   zone_id = data.aws_ssm_parameter.wca_zone_id.value
-  name    = "scramble"
+  name    = "scramble-api"
   type    = "A"
 
   alias {

iac/variable.tf

@@ -53,3 +53,12 @@ variable "http_port" {
 variable "https_port" {
   default = "443"
 }
+
+variable "domain_name" {
+  default = "worldcubeassociation.org"
+}
+
+variable "org_name" {
+  description = "Organization's identifier"
+  default     = "wca"
+}